U♯

U# — фортовское слово Каллисто.

U#             ( u −− u1 )                          Преобразовать в литеру последнюю цифру из u и добавить к форматной строке.

Преобразует одну цифру целого числа u и записывает её в выходной буфер PAD. Выдаёт цифру всегда. Если преобразовывать нечего, записывается '0'.

Ввод слова U#

В режиме ЛАТ последовательно нажмите клавиши  3     P   F   3 

Эти нажатия оставляют клавиатуру в режиме NUM.

# в стандарте ANS Forth

6.1.0030   #                            "number-sign"                      CORE
           ( ud1 -- ud2 )
           Делит ud1 числом в BASE, дает частное ud2 и остаток n. (n - младший 
           разряд ud1.) Преобразовывает n к внешней форме и добавляет 
           результирующий символ к началу выходной строки отображаемого числа. 
           Неопределенная ситуация существует если # выполняется вне <# #> 
           ограничивающих преобразование числа.
       См.: 6.1.0040 #>, 6.1.0050 #S, 6.1.0490 <#.

История

Каллистянское слово U# — адаптированное слово # , которое является стандартным и присутствует со времён Форта−79.

Каллистянское U# оперирует лишь с одной ячейкой на вершине стека. Слово U# также присутствует в некоторых версиях Форта, откуда и было взято его имя.

# в предыдущем стандарте Forth-83 (англ.)

     #            +d1 -- +d2                    79             "sharp"
          The remainder of +d1 divided by the value of BASE is
          converted to an ASCII character and appended to the output
          string toward lower memory addresses.  +d2 is the quotient
          and is maintained for further processing.  Typically used
          between <# and #> .

# в стандарте Forth-79 (англ.)

#              ud1 -- ud2                    158            "sharp"
    Generate  from  an unsigned double number d1,  the next  ASCII
    character which is placed in an output string.   Result d2  is
    the  quotient after division by BASE is maintained for further
    processing.  Used between <# and #> .

# в fig-FORTH Release 1 glossary, май 1979 (англ.)

#              d1  ---  d2                       L0
       Generate from a double number d1, the next ascii character which is
       placed in an output string. Result d2 is the quotient after division
       by BASE, and is maintained for further processing. Used between <#
       and #>.
       See #S.

Реализация

3776 ;#Unum
3777 ; U#               ( u −− u1 )                          Преобразовать в литеру последнюю цифру из u и добавить к форматной строке.
3778 ; Преобразовать одну цифру целого числа и записать её в выходной буфер PAD
3779 ; Выдать цифру всегда, если преобразовывать нечего, записать '0'.
3780 LDIG:           .DB     2
3781                 .TEXT   "U#"                    ; ( x1 −− x2)
3782                 .DW     LSIGN
3783 DIG:            .DW CALL, BASE,UAT, SLMOD, SWAP, LITB
3784                 .DB 9
3785                 .DW OVER, LESS, ZBRAN,DIGI, LITB
3786                 .DB 39                          ; 7 если заглавные буквы
3787                 .DW PLUS
3788 DIGI:           .DW LITB
3789                 .DB 48
3790                 .DW PLUS, HOLD, EXIT

Реализация из SP-Forth 4.20:

: # ( ud1 -- ud2 ) \ 94
\ Делением ud1 на значение BASE выделить одну цифру с конца и
\ добавить ее в буфер форматного преобразования чисел,
\ оставив частное ud2.
\ Исключительная ситуация возникает, если использовать #
\ вне <# и #>, ограничивающивающих преобразование чисел.
  0 BASE @ UM/MOD >R BASE @ UM/MOD R>
  ROT DUP 10 < 0= IF 7 + THEN 48 + 
  HOLD
;

Советская реализация

Юрий Семёнов приводит следующее определение слова U# (стр. 100):

 : U#   BASE @ /MOD ROT 9 OVER < IF 7 + THEN '0' + HOLD ;

В ядре ФОРТ-ЕС слово U# работало с числовой парой и называлось #

Вот его описание и определение:

#         D1->D2 ДЕЛЕНИЕМ D1 НА ЗНАЧЕНИЕ "BASE"                 37
          ВЫДЕЛИТЬ 1 ЦИФРУ С КОНЦА И ДОБАВИТЬ ЕЕ
          В БУФЕР "PAD", ОСТАВИВ ЧАСТНОЕ D2

                     Экран номер 37
( 31.03.86  PAD  HOLD  ALPHA  <# #> # #S SIGN )

CODE ALPHA ( N->C)  RW2 FIRST LH,
  RW1 RW1 SR,   RW1 1 =F (, RW2 IC,  PUTRW1 B,
  1 =H  C, ' 01234S478<?ABCDEFGHIJKLMNOPQRSTUVWXYZ'
END-CODE

: # ( D1->D2) BASE @ M/MOD ROT ALPHA HOLD ;

В FORTH ИТЭФ слово U# работало с числовой парой и называлось #

Вот его определение:

             HEAD    201Q,,243Q,DIG,$COL                  ; #
             DW  BASE,AT,MSMOD,ROT,LIT,11Q,OVER,LESS
             DW  ZBRAN,DIGI-$,LIT,7,PLUS
   DIGI:     DW  LIT,60Q,PLUS,HOLD,SEMI

Ссылки

• Исходный текст слова U# в Каллисто Классик 1.0
• См. HOLD, SIGN и DIGIT
• Слово # (number-sign) в стандарте ANS Forth (англ.)
• Слово # (number-sign) в черновике Forth 200x (англ.)
• ЧИСЛО ТИПОВ ЧИСЕЛ в книге Л.Броуди «Начальный курс программирования на языке Форт»
• A Number of Kinds of Numbers в книге Leo Brodie Starting Forth (англ.)

У этой статьи нет иллюстраций. Вы можете помочь проекту, добавив их.

Это заготовка статьи. Вы можете помочь проекту, дополнив её.